*WERS 2004 ERQ derived variables for FF.sps

*This syntax file derives the ERQ variables used in the 2004 First Findings publication.
*Last updated 31 July 2006.

*Before running this syntax, please ensure the file paths are changed throughout the file as necessary.
*These can be found by searching on the phrase 'Note file path' .
*Please note that it is also necessary to change the file paths in the separate file 'WERS 2004 MQ derived variables for FF.sps' for this syntax to run successfully .

************************************************.
*List of derived variables.
************************************************
** Type of rep (Xreptyp3, Xreptyp2)  .
** Hours spent on representative duties by representatives - banded (Xhours) .
** Time spent on reps activities - 3 bands (Xhours3)  .
** Whether full-time on representative duties (Xftrep)  .
** Whether spent any time on terms and conditions in the last 12 months (Xisstc)  .
** Whether rep spent any time on selection, development or staffing in the last 12 months (Xisssds)  .
** Whether representative spent any time on individual disputes in the last 12 months (Xissid)  .
** Whether representative spent any time on welfare issues (equal opportunities and health and safety) in the last 12 months (Xissw)  .
** Most important issue dealt with in past year (Ximpiss)  .
** Most important issue representative dealt with in past year - categories (Ximpiss2)  .
** Type of recruitment attempted by union rep (Xrectyp)  .
** Whether management provides office space (Xfacoff)  .
** Whether management provides office equipment (Xfacequip)  .
** Whether management provides meeting rooms (Xfacmeet)  .
** Whether management provides representatives with e-mail (Xfacemail)  .
** Whether management provides representatives with space on the company intranet (Xfacnet)  .
** Whether management provides representatives with other facilities (Xfacoth)  .
** Whether management provides no facilities to representatives (Xfacnone) .
** Whether reps of recognised unions are on-site or off-site (Xreptyp6)  .
** Whether managers trust union reps (hitrustmu) .
** Whether managers trust union reps (hitrustmnu) .
** Whether reps trust managers (hitrustw) .

***********************************************************************************************************************************.
*Run MQ derived variables syntax as need to match this on to ERQ data in order to derive some of the variables.
***********************************************************************************************************************************.

*Note file path .

include 'C:\WERS\WERS 2004 MQ derived variables for FF.sps'.

*Note file path .

*Save.
save outfile='C:\WERS\WERS 2004 MQ with derived variables.sav'.

********************************************************************.
*Then match ERQ data with MQ data .
********************************************************************.
*Note file path .

*Open ERQ data.
GET FILE='C:\WERS\xs04_erq.sav'.
execute.

*Note file path .

*Match ERQ with MQ data.
match files file=*/table='C:\WERS\WERS 2004 MQ with derived variables.sav'/by serno.
execute.


******************************************************* .
*Derived variables from ERQ data.
******************************************************* .

COMMENT	Type of rep (Xreptyp3, Xreptyp2)  .

Numeric Xreptyp3 (f2.0) .
recode wareptyp (1,2=1) (3=2) (4=3) (else=-9) into Xreptyp3 .
variable labels Xreptyp3 "Type of worker representative" .
value labels Xreptyp3
	1	"Union rep"
	2	"Non-union JCC rep"
	3	"Non-union stand-alone rep" .
missing values Xreptyp3 (-9) .
execute .

Numeric Xreptyp2 (f2.0) .
recode wareptyp (1,2=1) (3,4=2) (else=-9) into Xreptyp2 .
variable labels Xreptyp2 "Type of worker representative" .
value labels Xreptyp2
	1	"Union rep"
	2	"Non-union rep".
missing values Xreptyp2 (-9) .
execute .

******************************************************* .
COMMENT	Hours spent on representative duties by representatives - banded (Xhours) .

Numeric Xhours (f2.0) .
do if missing(wahrswrk)=0 .
+ recode wahrswrk (1=1) (2 thru 4=2) (5 thru 9=3) (10 thru hi=4) (else=-9) into Xhours . 
else if missing(wahrswrk)=1 and missing(wahrdk)=0 .
+ recode WAHRDK (1,2=1) (3=2) (4=3) (5=4) (else=-9) into XHOURS.
else if missing(wahrswrk)=1 and missing(wahrdk)=1.
+ compute xhours=-9.
end if . 
variable labels Xhours "Hours spent on rep activities by rep".
value labels Xhours	
			1	'1 hour'
			2	'2 to 4 hours'
			3	'5 to 9 hours'
			4	'10 hours or more'
			-9	'Not answered'.
missing values Xhours (-9).
execute.

******************************************************* .

COMMENT	Time spent on reps activities - 3 bands (Xhours3)  .

Numeric Xhours3 (f2.0) .
do if missing(xhours)=0 .
+ recode xhours (4=3) (else=copy) into Xhours3 . 
end if . 
variable labels Xhours3 "Hours spent on rep activities by rep".
value labels Xhours3	
			1	'1 hour'
			2	'2 to 4 hours'
			3	'5 hours or more'
			-9	'Not answered'.
missing values Xhours3 (-9).
execute.

******************************************************* .
COMMENT	Whether full-time on rep duties (Xftrep)  .

Numeric Xftrep (f2.0) .
do if missing(wahours) or missing(wahrswrk) .
+ compute Xftrep=-9 .
else .
+ compute Xftrep=(wahours<=wahrswrk)  .
end if .
missing values xftrep (-9) .
variable labels Xftrep "Whether full-time on rep duties" .
value labels xftrep 
	1	"Full-time"
	0	"Part-time"
	-9	"DK/NA" .
execute. 

******************************************************* .
COMMENT 	Whether spent any time on terms and conditions in the last 12 months (Xisstc)  .

Numeric Xisstc (f2.0) .
Do if missing(waprot01)=1 .
+ compute Xisstc=-9 .
else if missing(waprot01)=0 .
+ compute Xisstc=(any(1, waprot01 to waprot13,xwaprot1 to xwaprot3) or any(2, waprot01 to waprot13,xwaprot1 to xwaprot3) 
	or any(3, waprot01 to waprot13,xwaprot1 to xwaprot3)  or any(4, waprot01 to waprot13,xwaprot1 to xwaprot3))   . 
end if .
variable labels Xisstc "Whether spent any time on terms and conditions in the last 12 months" .
value labels Xisstc
	1	'Yes'
	0	'No'
	-9	'Not answered' .
missing values Xisstc (-9) .
execute .

******************************************************* .
COMMENT	Whether rep spent any time on selection, development or staffing in the last 12 months (Xisssds)  .

Numeric Xisssds (f2.0) .
Do if missing(waprot01)=1 .
+ compute Xisssds=-9 .
else if missing(waprot01)=0 .
+ compute Xisssds=(any(5, waprot01 to waprot13,xwaprot1 to xwaprot3) or any(6, waprot01 to waprot13,xwaprot1 to xwaprot3) 
	or any(9, waprot01 to waprot13,xwaprot1 to xwaprot3)  or any(12, waprot01 to waprot13,xwaprot1 to xwaprot3)) 
	or any(15, waprot01 to waprot13,xwaprot1 to xwaprot3)     . 
end if .
variable labels Xisssds "Whether representative spent any time on selection, development or staffing in the last 12 months" .
value labels Xisssds
	1	'Yes'
	0	'No'
	-9	'Not answered' .
missing values Xisssds (-9) .
execute .
******************************************************* .
COMMENT  	Whether representative spent any time on individual disputes in the last 12 months (Xissid)  .

Numeric Xissid (f2.0) .
Do if missing(waprot01)=1 .
+ compute Xissid=-9 .
else if missing(waprot01)=0 .
+ compute Xissid=(any(7, waprot01 to waprot13,xwaprot1 to xwaprot3) or any(8, waprot01 to waprot13,xwaprot1 to xwaprot3)) 
	. 
end if .
variable labels Xissid "Whether representative spent any time on individual disputes in the last 12 months" .
value labels Xissid
	1	'Yes'
	0	'No'
	-9	'Not answered' .
missing values Xissid (-9) .
execute .

******************************************************* .
COMMENT 	Whether representative spent any time on welfare issues (equal opportunities, health and safety or absence/sickness) in the last 12 months (Xissw)  .

Numeric Xissw (f2.0) .
Do if missing(waprot01)=1 .
+ compute Xissw=-9 .
else if missing(waprot01)=0 .
+ compute Xissw=(any(10, waprot01 to waprot13,xwaprot1 to xwaprot3) or any(11, waprot01 to waprot13,xwaprot1 to xwaprot3) 
	or any(14, waprot01 to waprot13,xwaprot1 to xwaprot3)) .
end if .
variable labels Xissw "Whether representative spent any time on welfare issues (equal opps, H&S, absence/sickness) in the last 12 months" .
value labels Xissw
	1	'Yes'
	0	'No'
	-9	'Not answered' .
missing values Xissw (-9) .
execute .

******************************************************* .
COMMENT	Most important issue dealt with in past year (Ximpiss)  .

Numeric Ximpiss (f2.0) .
Do if missing(waprot01)=1 .
+ compute Ximpiss=-9 .
else if missing(waprot01)=0 and missing(waprot02)=1.
+ compute Ximpiss=waprot01.
else if missing(waprot01)=0 and missing(waprot02)=0.
+ recode waprotim (-9,-8=-9) (else=copy) into ximpiss .
end if .
variable labels ximpiss "Most important issue dealt with in past year" .
value labels Ximpiss
	1 	'Rates of pay'
	2	'Hours of work'
	3	'Holiday entitlements'
	4	'Pension entitlements'
	5	'Recruitment or selection of employees'
	6	'Training of employees'
	7	'Disciplinary matters'
	8	'Grievances'
	9	'Staffing levels'
	10	'Equal opportunities'
	11	'Health and safety'
	12	'Performance appraisals'
	13		'Other issues'
	14		'None of these issues are important' 
	-9		'Not answered' .
missing values Ximpiss (-9) .
execute .

******************************************************* .

COMMENT	Most important issue representative dealt with in past year - categories (Ximpiss2)  .

Numeric Ximpiss2 (f2.0) .
recode Ximpiss (1 thru 4=1) (5 thru 6, 9, 12, 15=2) (7 thru 8=3) (10 thru 11=4) (13=5) (14=6) (else=-9) into Ximpiss2 .
variable labels Ximpiss2 "Most important issues dealt with in last year by category" .
value labels Ximpiss2
	1	'Terms and Conditions'
	2	'Selection, development and staffing'
	3	'Individual disputes'
	4	'Welfare'
	5	'Other' 
	6	'None of these issues are important'
	-9	'Not answered'.
missing values Ximpiss2 (-9) .
execute .

******************************************************* .
COMMENT	Type of recruitment attempted by union rep (Xrectyp)  .

Numeric Xrectyp (f2.0) .
do if missing(wjtried)=0 and wjtried=1 .
+ do if missing(wjinfill) and missing(wjexpan) .
+ compute Xrectyp=-9 .
+ else if missing(wjinfill)=0 and wjinfill=2 and missing(wjexpan)=0 and wjexpan=2 .
+ compute xrectyp=-8 .
+ else if missing(wjinfill)=0 and wjinfill=1 and missing(wjexpan) .
+ compute xrectyp=-7 .
+ else if missing(wjexpan)=0 and wjexpan=1 and missing(wjinfill) .
+ compute xrectyp=-6 .
+ else if missing(wjinfill)=0 and wjinfill=1 and missing(wjexpan)=0 and wjexpan=2 .
+ compute xrectyp=3 .
+ else if missing(wjinfill) and missing(wjexpan)=0 and wjexpan=2 .
+ compute xrectyp=3 .
+ else if missing(wjinfill)=0 and wjinfill=2 and missing(wjexpan)=0 and wjexpan=1 .
+ compute xrectyp=2 .
+ else if missing(wjinfill)=0 and wjinfill=2 and missing(wjexpan) .
+ compute xrectyp=2 .
+ else if missing(wjinfill)=0 and wjinfill=1 and missing(wjexpan)=0 and wjexpan=1 .
+ compute xrectyp=1.
+ end if .
else .
+ compute Xrectyp=-1 .
end if .
missing values xrectyp (-9 thru -1) .
value labels Xrectyp 
	1	"Infill and expansion"
	2	"Expansion only"
	3	"Infill only"
	-1	"Not applicable (Wjtried~=1)"
	-6	"Expansion, DK if infill"
	-7	"Infill, DK if expansion"
	-8	"No at Wjinfill and Wjexpan"
	-9	"DK/NA both questions" .
execute .

******************************************************* .
COMMENT	Facilities provided for reps (Xfacoff, Xfacequip, Xfacmeet, Xfacemail, Xfacnet, Xfacoth, Xfacnone)  .

COMMENT 	Whether management provides office space (XFACOFF) .

Numeric Xfacoff (f2.0) .
Do if missing(wephon01)=1 .
+ compute xfacoff=-9 .
else if missing(wephon01)=0 .
+ compute Xfacoff=(any(2, wephon01 to wephon10,xwephon1 to xwephon3) or any(3, wephon01 to wephon10,xwephon1 to xwephon3)). 
end if .
variable labels Xfacoff "Whether management provides office space facilities for representative duties" .
value labels Xfacoff
	1	'Yes'
	0	'No'
	-9	'Not answered' .
missing values Xfacoff (-9) .
execute .

COMMENT 	Whether management provides office equipment (XFACEQUIP)  .

Numeric Xfacequip (f2.0) .
Do if missing(wephon01)=1 .
+ compute Xfacequip=-9 .
else if missing(wephon01)=0 .
+ compute Xfacequip=(any(1, wephon01 to wephon10,xwephon1 to xwephon3) or any(5, wephon01 to wephon10,xwephon1 to xwephon3) 
	or any(6, wephon01 to wephon10,xwephon1 to xwephon3) or any(11, wephon01 to wephon10,xwephon1 to xwephon3)
	or any(12, wephon01 to wephon10,xwephon1 to xwephon3) or any(13, wephon01 to wephon10,xwephon1 to xwephon3)). 
end if .
variable labels Xfacequip "Whether management provides office equipment for representative duties" .
value labels Xfacequip
	1	'Yes'
	0	'No'
	-9	'Not answered' .
missing values Xfacequip (-9) .
execute .


COMMENT 	Whether management provides meeting rooms (XFACMEET)  .

Numeric Xfacmeet (f2.0) .
Do if missing(wephon01)=1 .
+ compute Xfacmeet=-9 .
else if missing(wephon01)=0 .
+ compute Xfacmeet=(any(4, wephon01 to wephon10,xwephon1 to xwephon3)).
end if .
variable labels Xfacmeet "Whether management provides meeting rooms for representative duties" .
value labels Xfacmeet
	1	'Yes'
	0	'No'
	-9	'Not answered' .
missing values Xfacmeet (-9) .
execute .

COMMENT 	Whether management provides representatives with e-mail (XFACEMAIL)  .

Numeric Xfacemail (f2.0) .
Do if missing(wephon01)=1 .
+ compute Xfacemail=-9 .
else if missing(wephon01)=0 .
+ compute Xfacemail=(any(7, wephon01 to wephon10,xwephon1 to xwephon3)).
end if .
variable labels Xfacemail "Whether management provides e-mail for representative duties" .
value labels Xfacemail
	1	'Yes'
	0	'No'
	-9	'Not answered' .
missing values Xfacemail (-9) .
execute .

COMMENT 	Whether management provides representatives with space on the company intranet (XFACNET) .

Numeric Xfacnet (f2.0) .
Do if missing(wephon01)=1 .
+ compute Xfacnet=-9 .
else if missing(wephon01)=0 .
+ compute Xfacnet=(any(8, wephon01 to wephon10,xwephon1 to xwephon3)).
end if .
variable labels Xfacnet "Whether management provides intranet for representative duties" .
value labels Xfacnet
	1	'Yes'
	0	'No'
	-9	'Not answered' .
missing values Xfacnet (-9) .
execute .


COMMENT 	Whether management provides representatives with other facilities (XFACOTH)  .

Numeric Xfacoth (f2.0) .
Do if missing(wephon01)=1 .
+ compute Xfacoth=-9 .
else if missing(wephon01)=0 .
+ compute Xfacoth=(any(95, wephon01 to wephon10,xwephon1 to xwephon3)).
end if .
variable labels Xfacoth "Whether management provides other facilities for representative duties" .
value labels Xfacoth
	1	'Yes'
	0	'No'
	-9	'Not answered' .
missing values Xfacoth (-9) .
execute .


COMMENT 	Whether management provides no facilities to representatives (XFACNONE)  .

Numeric Xfacnone (f2.0) .
Do if missing(wephon01)=1 .
+ compute Xfacnone=-9 .
else if missing(wephon01)=0 .
+ compute Xfacnone=(any(10, wephon01 to wephon10,xwephon1 to xwephon3)).
end if .
variable labels Xfacnone "Whether management provides no facilities for representative duties" .
value labels Xfacnone
	1	'Yes'
	0	'No'
	-9	'Not answered' .
missing values Xfacnone (-9) .
execute .

******************************************************* .
COMMENT	Whether reps of recognised unions are on-site or not (Xreptyp6)  .

missing values estewext () .

Numeric Xreptyp6 (f2.0) .
do if wareptyp=1 .
+ do if (missing(estewext)=0 and estewext=-1) .
+ compute Xreptyp6=1 .
+ else if (missing(estewext)=0 and estewext=2)  .
+ compute Xreptyp6=1 .
+ else if missing(estewext)=0 and estewext=1 .
+ compute Xreptyp6=2 .
+ end if .
else if wareptyp>1 .
+ compute Xreptyp6=(wareptyp+1) .
end if .
missing values Xreptyp6 (-9, -8) .
variable labels Xreptyp6 "Type of employee representative" .
value labels Xreptyp6
	1	"Rep of recognised union: on-site"
	2	"Rep of recognised union: off-site"
	3	"Rep of non-recognised union"
	4	"Non-union JCC rep"
	5	"Stand-alone non-union rep" .
execute .

**************************************************************** .
COMMENT	Trust between managers and reps (hitrustmu, hitrustmnu, hitrustw)  .

do if any(xreptyp6,1,3)=1 .
+ recode etrusa1 etrusa2 etrusa3 (1,2=1) (3,4,5=0) into etrusa1b etrusa2b etrusa3b .
else if xreptyp2=2 .
+ recode etrusb1 etrusb2 etrusb3 (1,2=1) (3,4,5=0) into etrusb1b etrusb2b etrusb3b .
end if .
do if any(xreptyp6,1,3)=1 or xreptyp2=2 .
+ recode whtrust1 whtrust2 whtrust4 (1,2=1) (3,4,5=0) into whtrust1b whtrust2b whtrust4b .
end if .

compute hitrustmu=(sum.3(etrusa1b,etrusa2b,etrusa3b)=3) .
compute hitrustmnu=(sum.3(etrusb1b,etrusb2b,etrusb3b)=3) .

compute hitrustw=(sum.3(whtrust1b,whtrust2b,whtrust4b)=3) .

variable labels hitrustmu "Whether managers trust union reps" .
value labels hitrustmu
	1	"Managers trust reps"
	0	"Managers do not trust reps".

variable labels hitrustmnu "Whether managers trust union reps" .
value labels hitrustmnu
	1	"Managers trust reps"
	0	"Managers do not trust reps".

variable labels hitrustw "Whether reps trust managers" .
value labels hitrustw
	1	"Reps trust managers"
	0	"Reps do not trust managers".
execute .
**************************************************************** .